Xlorep DarkHelm's overly complex useful macros...

[:1]Ok... so before I start, let me explain, I am a sucker for setting up logic puzzles, which is one of the big draws that programming has always had for me. The macro system has become so integrated in how I play WoW, I honestly can't really play my characters very well without them. I don't know how useful these would be for people other than me, but they should at least give some people ideas on what can be done with macros, at the very least. They are all built around my particular style of gameplay, and are not necessarily a "good fit" for others.

I'm going to stick with my level 70 characters' macros... because those are the ones that I like the most. The others I still fidget with quite a bit.

Since I have two hunters, and they were my first 70's... and they share a number of macros, I'll start with them. There are a number of macros the two share... things that are not so reliant on the particular build/concept I have for the characters. Most are quite simple:

Heal Pet:


Code:

#showtooltip
/cast [target=pet, nodead, exists] Mend Pet; Revive Pet

Real simple macro, if I have a pet that isn't dead and is out, it is Mend Pet, otherwise it is Revive Pet. Basically, the idea is that I won't mend and revive a pet at the same time...

Call/Dismiss Pet:


Code:

#showtooltip
/cast [target=pet, nodead, exists] Dismiss Pet; Call Pet

Like the Heal Pet, I never would be in a situation where I call a pet and dismiss the pet at the same time, so this saves some bar real estate by combining the two into one button.

Fire Trap


Code:

#showtooltip
/cast [nomod:alt] Immolation Trap; Explosive Trap

I had a problem where I would hit the wrong trap button between explosive and immolation traps (also freezing and frost). This basically makes it so that if I want to use Explosive Trap, I have to press alt to do so, preventing me from accidentally pressing the wrong one.

Ice Trap


Code:

#showtooltip
/cast [nomod:alt] Freezing Trap; Frost Trap
/stopattack [nomod:alt]

Like with the Fire Traps... I had a problem of accidentally pressing the wrong trap button for frost or freezing traps. This pretty much prevents me from making that mistake. It also helps me avoid accidentally breaking my own freezing trap by stopping me from hitting what I just froze...

Melee


Code:

#showtooltip
/cast [mod] !Aspect of the Viper; !Aspect of the Monkey
/changeactionbar 2

Ranged


Code:

#showtooltip
/cast [mod] !Aspect of the Viper; !Aspect of the Hawk
/changeactionbar 1

These two serve the purpose of changing my action bar from the first one (which I have my ranged attacks on) and the second one (which has the melee attacks on). It also will cast Aspect of the Hawk or Aspect of the Monkey depending on if it is ranged or melee respectively, unless I press alt, shift, or ctrl when I press these buttons which then makes it cast Aspect of the Viper instead.

I tend to place these two buttons in slots 1 & 2 on both of the action bars, so they never change, only the rest of the buttons in the bars change...

Misdirection


Code:

#showtooltip
/cast [target=focus,exists][help,exists][target=pet,exists][exists] Misdirection; Misdirection

My simple Misdirection macro... if I have a Focus... it will cast misdirection on that focus, otherwise it tries whatever I have targeted if it is friendly, otherwise it tries my pet, otherwise I have to pick it. This lets me quickly cast Misdirection on the tank before I do something like an Aimed Shot at the start of the fight... so I don't do things like pull aggro off the tank really fast.


Code:

#showtooltip
/cast [nomod:alt] Multi-Shot; Volley

I don't use Volley much, and wanted to free up some bar room. So I wrapped it up with my multi-shot. I just press Alt to get Volley instead.

Those are the macros my hunters share. However, there is a number of macros that they don't share, which are related to the two. Oguler, my Orc Beast Mastery spec'ed hunter has a few specialized macros...

Hunter Melee:


Code:

#showtooltip
/cast [mod:shift] Disengage; Raptor Strike
/stopmacro [mod:shift]
/cast Wing Clip

Since Oguler is Beast Mastery, he has no special abilities with melee attacks beyond the normal set for Hunters, so his melee macro is pretty simple. It does Raptor Strike & Wing Clip simultaneously, unless I hold down shift, then it does Disengage.

Feed Pet:


Code:

#showtooltip Telaari Grapes
/stopmacro [nopet][target=pet,dead]
/cast Feed Pet
/use Telaari Grapes

Oguler has a big bat as his main pet (or a Dragonhawk currently as his secondary pet). Bats eat grapes, and this is a simple feed pet macro...

Intimidate This


Code:

#showtooltip
/castsequence Intimidation,Rapid Fire,Intimidation,Bestial Wrath,Core of Ar'kelos,Intimidation,Blood Fury,Ogre Mauler's Badge,Intimidation,Bestial Wrath,Core of Ar'kelos,Intimidation,Blood Fury,Ogre Mauler's Badge

This is more or less the "bread and butter" macro that controls all of Oguler's little cooldown-based buffs he has. Using Intimidate's shorter cooldowns, I've more or less broken everything up so there's something happening every minute as it cycles through the process.

Shots


Code:

#showtooltip
/target [target=focustarget,exists]
/castsequence [nocombat,nomodifier:ctrl/alt][combat,modifier:ctrl] Aimed Shot; Arcane Shot, Steady Shot, Steady Shot, Steady Shot, Steady Shot
/petattack [nomodifier:shift]

Oguler's main spammed ranged attack macro. If I have a focus, it automatically sets me to target what my focus targets... making this into an instant assist macro when necessary. Otherwise, it leads in with an Aimed Shot, followed by a series of Arcane Shots and Steady Shots. It also will send his pet in to attack the target, sort of keeping a "tight leash" on what my pet is doing.

Something to note is that I have the Aimed Shot & Arcane Shot/Scatter Shot sequence switch in the macro depending on if I'm in combat or not. If I'm in combat, the main operation of the macro is Arcane Shot/Steady Shot, but pressing Ctrl will switch to Aimed Shot. When I'm out of combat, that switches so that the button defaults to Aimed Shot & pressing Ctrl does the next Arcane Shot/Steady Shot int he sequence.

Stings


Code:

#showtooltip
/cast [mod:ralt] Tranquilizing Shot; [mod:lalt] Viper Sting; [mod:shift] Scorpid Sting; Serpent Sting

Wraps up all of Oguler's various stings into one convenient package. I put Tranq Shot on this macro... basically so I can access it if I really need to, but otherwise it just doesn't take up any bar real estate.

Travel


Code:

#showtooltip
/cast [nocombat,outdoors,flyable,nomod]Blue Windrider;[nocombat,outdoors,nomod:alt/ctrl]Swift Blue Raptor;[group][mod:alt]Aspect of the Pack;Aspect of the Cheetah

This is my "one button for all travel options" macro. Uses the flying mount, ground mount, Aspect of the Pack or Cheetah as is relevant.

For Sorlina, my Survival/Marksmanship spec'ed Dwarf Hunter who's an Engineer... her set of macros are a bit different.

Feed Pet:


Code:

#showtooltip [nomod] Smoked Talbuk Venison; Kibler's Bits
/stopmacro [nopet][target=pet,dead]
/cast [nomod] Feed Pet
/use [nomod] Smoked Talbuk Venison; Kibler's Bits

Sorlina's cooking is a bit better than Oguler's. Her pets are a Boar or a Cat, so she uses meat for them both. She also keeps a stack of [item]Kibler's Bits[/item] available for when she wants a little extra help for her pets.

Looking


Code:

#showtooltip
/cast [mod] Surestrike Goggles v2.0; Eagle Eye

Just a convenient way to wrap together the [item]Surestrike Goggles v2.0[/item] with Eagle Eye.

Hunter Melee


Code:

#showtooltip
/cast [mod:shift] Disengage; [mod:alt] Scatter Shot; Raptor Strike
/stopmacro [mod:shift/alt]
/cast Wing Clip
/petattack [mod:ctrl]

Sorlina, being 30 points into Marksmanship, has Scatter Shot. Set to operate through the alt key, it's my "oh crap" button, or a good quick way for me to stop a spell from being cast... getting out of melee range... etc. Otherwise this is quite similar to Oguler's version.

Rapid/Stone


Code:

#showtooltip
/cast [mod:alt] Stoneform; Rapid Fire

Where Oguler has a very complex macro handling trinkets, beast mastery talents, Rapid Fire, and his racial ability in a sequence, Sorlina's is significantly simpler.

Shots


Code:

#showtooltip
/target [target=focustarget,exists]
/castsequence [nocombat,nomod:ctrl/alt][combat,mod:ctrl] Aimed Shot; [mod:alt] Scatter Shot; Arcane Shot, Steady Shot, Steady Shot, Steady Shot, Steady Shot
/petattack

Like with Oguler, this is Sorlina's main spammable ranged attacks... But, unlike Oguler, she has Scatter Shot and I added it into the mix with the Alt key.

Stings


Code:

#showtooltip
/cast [mod:ralt] Tranquilizing Shot; [nocombat,nomodifier][combat,mod:ctrl] Wyvern Sting; [mod:lalt] Viper Sting; [mod:shift] Scorpid Sting; Serpent Sting

Sorlina's set of stings includes Wyvern Sting. Which is set up to switch between it and Serpent Sting much like how my Shots switch out the Aimed Shot & Arcane shot/Steady Shot sequences depending on if I'm in combat or not.

Travel


Code:

#showtooltip
/cast [nocombat,outdoors,flyable,nomodifier]Turbo-Charged Flying Machine Control;[nocombat,outdoors,nomod:alt/ctrl]Black Battlestrider;[group][mod:alt]Aspect of the Pack;Aspect of the Cheetah

Sorlina's version of the Travel Macro

Trinket 1


Code:

#showtooltip
/use [nomod] 13
/equipslot [mod:alt] 13 Skyguard Silver Cross; [mod:ctrl] 13 Power Infused Mushroom; [mod:shift] 13 Goblin Jumper Cables

Trinket 2


Code:

#showtooltip
/use [nomod] 14
/equipslot [mod:shift] 14 Ultrasafe Transporter: Toshley's Station; [mod:ctrl] 14 Gnomish Poultryizer; [mod:alt] 14 Ultrasafe Transporter: Gadgetzan

These are the two trinket macros that Sorlina has... she has a set of different trinkets, a lot because she's an Engineer. The idea is that I just press the macro to use whatever trinket is in the different slots, but holding shift, alt, or ctrl will let me swap out which trinket is equipped in that slot.

Well... these are my Hunters' macros. I have a set for Druids, and one for Warriors currently as well...|||*claps*

awesome stuff!|||Glad you like, I added the call/dismiss pet macro to the list... somehow I missed one of the primary ones my hunters share. These all more or less work with the way I play my hunters, and I tend to set up their buttons so that the same or similar macros are on the same positions on their bars... which doesn't exactly help with my ability to remember which hunter I'm playing at the time... but helps with being able to instinctively remember where the buttons for certain things are at.

My Druid macros can get a bit more complex... especially the "travel" macro that combines a whole LOT of different things into a single button. But currently, the most complex macro I have is on my Warrior, which actually spans 3 buttons.

oh, here's my bandage button:

Bandage


Code:

#showtooltip
/use [button:2,target=pet,nodead,exists][noharm,nodead][target=player] Heavy Netherweave Bandage

Basically, if I have a pet, and it is able to be bandaged, I can click the right mouse button to bandage my pet, and the left button to bandage myself (or my target if it is friendly). I don't have this on a button I have hotkeyed, and since it is merely changing targets rather than abilities, I went with a different mouse button rather than pressing alt, ctrl, or shift (which I tend to save for where I am using a different spell/ability).|||Ok, moving onto my druid macros. Like with the hunter macros above... this is a set of macros that are useful for my particular style of gameplay, and may not be best for others. But maybe it can help give some ideas to people for how to build/set up their own macros.

Bear:


Code:

#showtooltip
/cast [nomod] Dire Bear Form;[mod:ctrl,form:1/2]War Stomp;!Dire Bear Form

This macro lets me cast Dire Bear Form... Normal operation is to toggle between Dire Bear Form and caster form. If I press ctrl and am in Dire Bear or Cat forms, it does my racial War Stomp. If I press alt, it recasts Dire Bear Form without toggling, helping me get out of roots/snares/etc.

Bear Melee:


Code:

#showtooltip
/startattack
/castsequence [mod:alt] Swipe;[mod:ctrl]Demoralizing Roar;reset=target/combat Mangle (Bear)(),Lacerate,Maul,Maul

this is my "spammable" macro when in bear form. It lets me handle most of my main melee attacks in a nice handy-dandy sequence, if I hold down alt I can swipe as needed, if I press ctrl I have my demoralizing roar.

Buffs:


Code:

#showtooltip
/castsequence [group,nomod]Gift of the Wild; [mod:shift]Omen of Clarity;[mod:alt]Thorns; [mod:ctrl]Mark of the Wild;reset=shift Mark of the Wild,Omen of Clarity,Thorns,Thorns,Thorns

This cycles my buffs for me, and gives me access to various buffs by pressing different modifiers

Cat:


Code:

#showtooltip
/cast [nomod] Cat Form;[mod:ctrl,noform]Faerie Fire;[mod:ctrl,form:1/2]Faerie Fire (Feral)();!Cat Form

Much like my Bear macro, this handles shifting to Cat Form. It also wraps in the functionality for me to use Faerie Fire (normal or Feral).

Cat Melee:


Code:

#showtooltip
/castsequence reset=target/combat Mangle (Cat)(),Rake,Mangle (Cat)(),Mangle (Cat)()

My cat form "spammable" attack macro. Cycles between the different attacks my cat form has.

Decurse:


Code:

#showtooltip
/cast [nomodifier] Abolish Poison; Remove Curse

Simple macro to wrap together the Remove Curse and Abolish Poison spells.

Healing:


Code:

#showtooltip
/castsequence [mod:alt] Lifebloom; [mod:shift] Regrowth; [mod:ctrl] Rejuvenation; Regrowth, Rejuvenation, Lifebloom, Lifebloom, Lifebloom

Standard is to cycle between Regrowth, Rejuvination, and Lifebloom, I can cast each of those specifically by using a modifier key.

Maim:


Code:

#showtooltip
/cast Maim
/stopattack

Maim, being a form of CC, is one of those things I want to force myself to not do silly things like... break it. So I stop myself from attacking when I use it.

Sneaky Cat:


Code:

#showtooltip
/cast [nocombat, nostealth] Prowl; [combat, nostealth] Shred; [mod:alt] Ravage; Pounce

My macro I use for stealth & starting hits when I am stealthed.

Travel:


Code:

#showtooltip
/cast [swimming,mod:alt]!Aquatic Form;[swimming] Aquatic Form;[indoors,mod:alt]!Cat Form;[indoors]Cat Form;[mod:alt]Travel Form;[combat]!Travel Form;[flyable,nomod]Flight Form;Great Gray Kodo

Really complicated macro designed to pick the optimal/correct thing to change to depending on situation. It handles shifting to Aquatic Form, Travel Form, Flight Form, using my ground mount, or even Cat Form based on conditions. Sort of one-button for me to use as a "ack! run away!" button, or for basic travel functionality for me.|||hey xlorep... thanks for the druid macros. i've been thinking of rolling a druid so this really helps. one question that i dont know about macros is the use if the exclamation !.

can you please explain that?

also can you explain your healing macro a bit more? i know you have healing spells lined up in sequence, but the modifiers would get confusing. will the modifier only be recognized in the beginning of the macro? or would it overide the sequence when the macro has already started?

thanks!|||Quote:








hey xlorep... thanks for the druid macros. i've been thinking of rolling a druid so this really helps. one question that i dont know about macros is the use if the exclamation !.

can you please explain that?




Sure, with macros, the default operation for something that can be toggled, like a shapeshifted form, is that if you press it once, it turns it on, if you press it again, it turns it off, and keeps toggling it. Blizzard added the exclamation point (!) to force it to always just keep re-casting the effect, rather than toggling on/off. So, "/cast !Cat Form" in a macro would make it so you cast Cat Form when you press the macro every time. It basically would be going from Cat Form -> Cat Form. Since the act of casting a shapeshifted form breaks you out of snares & roots, what this does is basically make me stay in Cat Form, but get out from movement-impairing effects. This all works, because the act of casting a spell automatically breaks you out of a shapeshifted form now, and casting a shapeshift form spell is instant-cast. Rather than needing to hit the button twice (once for dropping the shapeshift form, and the second time to go back into it), I just press the button once to do it all.


Quote:




also can you explain your healing macro a bit more? i know you have healing spells lined up in sequence, but the modifiers would get confusing. will the modifier only be recognized in the beginning of the macro? or would it overide the sequence when the macro has already started?

thanks!






Ok, for my healing macro:


Code:

#showtooltip
/castsequence [mod:alt] Lifebloom; [mod:shift] Regrowth; [mod:ctrl] Rejuvenation; Regrowth, Rejuvenation, Lifebloom, Lifebloom, Lifebloom

This is a kind of logical branching, set up like: if x then a else if y then b else if z then c else d. The programmatic "pseudo-code" would look like:


Code:

if alt is pressed:
   cast Lifebloom
else if shift is pressed:
   cast Regrowth
else if ctrl is pressed:
   cast Rejuvination
else:
   cast in a repeating sequence:
      1st: Regrowth
      2nd: Rejuvenation
      3rd: Lifebloom
      4th: Lifebloom
      5th: Lifebloom

That "else" would be like saying that the condition before it failed. Whichever step turns out true, it does, otherwise it is false, and goes to the next expression to figure out if it is true, and so forth.

If I press Alt, I will cast Lifebloom. If I don't press Alt, but I press Shift, I will cast Regrowth; if I don't press Alt or Shift but press Ctrl, I will cast Rejuvination; if I don't press Alt, Shift, or Ctrl, then it casts the sequence I listed.

The more complicated macro that uses this if...else if...else if...else... sequencing is the travel macro:


Code:

#showtooltip
/cast [swimming,mod:alt]!Aquatic Form;[swimming] Aquatic Form;[indoors,mod:alt]!Cat Form;[indoors]Cat Form;[mod:alt]Travel Form;[combat]!Travel Form;[flyable,nomod]Flight Form;Great Gray Kodo

Which the pseudo-code for it would read:


Code:

if I am swimming and I press Alt:
   recast Aquatic Form (no toggle)
else if I am swimming: (and not pressing Alt)
   cast Aquatic Form (toggle)
else if I am indoors and I press Alt:
   recast Cat Form (no toggle)
else if I am indoors:
   cast Cat Form (toggle)
else if I press Alt: (and am not swimming or indoors)
   cast Travel Form (toggle)
else if I am in combat: (and am not swimming or indoors or pressing Alt)
   recast Travel Form (no toggle)
else if I am in an area I can fly and don't press Shift or Ctrl: (I already am not pressing Alt, and of course I am not swimming, indoors, or in combat)
   cast Flight Form
else: (I am not swimming, indoors, in combat, pressing Alt, and am not in an area I can fly; OR I am not swimming, indoors, in combat, pressing alt, and AM pressing Ctrl or Shift)
   use my Great Gray Kodo (land mount)

I noted things that were implied on each step in the above in parentheses.

The thing to remember is that for each semicolon "section", everything after one section is automatically implied that the preceding sections were not true.

Also, remember that a casting sequence changes to the next in a sequence for each time you press the button. So, for my healing macro, the first time I cast it is Regrowth, the second time is Rejuvination, the third, fourth, and fifth presses would be Lifebloom, the sixth press would be Regrowth, and so on. If I press Alt, Ctrl, or Shift, this doesn't affect the sequence at all, it just lets me have access to those three spells outside the sequence if I need them.|||And now for my Warrior macros I currently am using. My Warrior is my most recent level 70... and as such, I might fiddle with these a bit.

Something I'll explain right away... I find the female gnome voice emotes to be really an ironic "mismatch" to all of the killing and such in the game. It's just.... too cutsey. As such, I decided to integrate the voice emotes into a LOT of my warrior's macros -- for the irony. And it usually gets a good laugh. I make sure it isn't the macros I press a LOT of during a fight, only those things I might do once in a while.

Bash/Pummel:


Code:

#showtooltip
/cast [stance:2] Shield Bash; [stance:3] Pummel
/stopmacro [nocombat][noharm][dead]
/no

Ok, this is one of the macros that exists just so I have a little voice emote whenever I shield bash or pummel. I tell my opponent "No" when I prevent them from casting spells for a few seconds...

Weapon Swap:


Code:

#showtooltip
/equipslot [equipped:shield] 16 Mag'hari Fury Brand; 16 Crystalline Kopesh
/equipslot [equipped:shield] 17 Diamond Tipped Claws of the Champion; 17 Iron Oak Shield

Ok, this one is fairly straight-forward. I click it to swap my two one-handed DPS weapons with my tanking sword & shield. This macro is important, as it is actually part of the next two-macro combination:

Charge:


Code:

#showtooltip
/cast [mod:alt,noform:2]Defensive Stance;[mod:alt]Intervene;[combat,noform:3][mod:ctrl,noform:3]Berserker Stance;[nocombat,noform:1][mod:ctrl,noform:1]Battle Stance;[form:3]Intercept;Charge
/click MultiBarRightButton1

Charge Part 2:


Code:

#showtooltip Attack
/startattack [button:2]
/stopmacro [button:2]
/click [noequipped:shield,mod][equipped:shield,nomod] BonusActionButton12
/stopmacro [dead][noharm][nocombat,noform:1][combat,noform:3][mod,noform:2]
/charge

Ok, possibly the longest macro I've done, it spans 3 buttons! It basically started with a simple premise -- I wanted a single button for Charge, Intercept, and Intervene... which are, in many ways, very similar abilities with different intents/purposes. But, they only work in a given stance... and I wanted a way to be able to switch to use them all in one (and add the voice emote for /charge when appropriate). I also tagged on the ability to automatically switch out my weapons for whatever is appropriate for a particular stance.

The basic structure is:

• Pressing Alt
  • If in Defensive Stance
    • Intervene
    
    
  
  
  • If not in Defensive Stance
    • Switch to Defensive Stance
    
    
  
  


• Not Pressing Alt
  • If in combat, but not in Berserker Stance, OR If I press Ctrl and not in Berserker Stance
    • Switch to Berserker Stance
    
    
  
  
  • If not in combat, and not in Battle Stance, OR If I press Ctrl and am not in Battle Stance
    • Switch to Battle Stance
    
    
  
  
  • If in Berserker Stance (and in combat)
    • Intercept
    
    
  
  
  • Else (I am in Battle Stance, and not in combat)
    • Charge
    
    
  
  

Then press Charge Part 2:

• If I right-click on this, turn auto attack on/off and stop.


• Else
  • If I am pressing Alt and I don't have a shield equipped OR I am not pressing Alt and I have a shield equipped.
    • press the weapon-swapper macro's button.
    
    
  
  
  Then:
  • If I am not casting Intercept, Charge, or Intervene, stop the macro.
  
  
  • Else do /charge voice emote
  
  

It is very, very complex, but works for me, for being a very easy way for me to swap out between stances, use Charge, Intercept, or Intervene, and swap out weapons as I need.

Combat Buffer:


Code:

#showtooltip
/castsequence [mod:alt] Escape Artist; [stance:1] Bloodrage, Battle Shout, Bloodrage; [stance:2] Bloodrage, Commanding Shout, Bloodrage; Bloodrage, Berserker Rage, Battle Shout, Berserker Rage, Bloodrage, Berserker Rage

This macro handles my various buffs. Since I can't do Battle Shout and Commanding Shout together, I figured that it made more sense for Commanding Shout to be cast when I'm in Defensive Stance, while Battle Shout to be in the mix for Berserker or Battle Stance. I have Berserker Rage added into the mix when I'm in Berserker Stance.

I also wrapped up my Escape Artist into this macro as something to quickly press when I use Alt.

Demoralizing/Clap:


Code:

#showtooltip
/castsequence [stance:3] Demoralizing Shout;  reset=combat Demoralizing Shout, Thunder Clap

Wraps up Demoralizing Shout and Thunder Clap into a single button for me, handing the scenario that there is no Thunder Clap in Berserker Stance.

Disarm


Code:

#showtooltip
/cast Disarm
/stopmacro [nocombat][noharm][dead]
/thank

I'm very polite when I disarm opponents.

Hamstring


Code:

#showtooltip
/cast Hamstring
/stopmacro [nocombat][noharm][dead]
/wait

I'm short. So I politely ask someone to slow down when they try to run away.

Intimidate


Code:

#showtooltip
/cast Intimidating Shout
/stopmacro [nocombat][noharm][dead]
/stopattack
/flee

Wouldn't the shrill voice of a little Gnome female be enough to make someone flee in terror?

Melee


Code:

#showtooltip
/startattack
/castsequence [mod:alt,noform:2]Execute;[form:3] Sunder Armor;reset=combat/target Sunder Armor,Rend,Sunder Armor,Sunder Armor,Sunder Armor
/stopmacro [nomod:alt][nocombat][noharm][dead][stance:2]
/bye

This is my spammable main melee attack macro. If I press Alt, I will Execute (and tell the opponent goodbye), otherwise I'm doing a lot of Sunder Armors and Rend (when applicable).

Piercing/Overpower/Revenge:


Code:

#showtooltip
/cast [mod:alt]Piercing Howl;[form:1]Overpower;[form:2]Revenge;[form:3]Whirlwind
/stopmacro [nomod:alt][nocombat][noharm][dead]
/wait

Overpower and Revenge wrapped up together, with Piercing Howl also added. Just like with Hamstring, I politely ask my opponent to slow down and waitup for my short little self.

Reflection


Code:

#showtooltip [noequipped:shield] Iron Oak Shield;Spell Reflection
/click [noequipped:shield] BonusActionButton12
/cast [equipped:shield] Spell Reflection
/stopmacro [nocombat][noharm][dead][noequipped:shield]
/congratulate

I check to see if I have a shield equipped, if not, I press the macro to swap my weapons. Otherwise I cast Spell Reflection and politely congratulate my opponent for successfully hurting him or herself.

Strike


Code:

#showtooltip
/cast [nomod] Heroic Strike;Cleave

Heroic Strike and Cleave all in one button, depending on if I press a modifier key or not (functionally, the two are *very* similar).

Taunt


Code:

#showtooltip
/cast [modifier:alt][stance:3] Challenging Shout; [stance:1] Mocking Blow; [stance:2] Taunt
/stopmacro [nocombat][noharm][dead]
/rasp

Combining Taunt, Challenging Shout, and Mocking Blow into a single button, with me doing a raspberry and being rude to my target at the same time.

Travel


Code:

#showtooltip
/use [flyable,nomod]Golden Gryphon;Great Blue Elekk

What can I say... Warriors don't have nearly the variety of travel options that Druids or Hunters do...

Shoot/Throw


Code:

#showtooltip
/cast [equipped:thrown] Throw; Shoot
/stopmacro [noharm][dead][nogroup]
/incoming

This one actually is a general macro I have to share across any of my characters with shoot or throw... so my Rogue currently uses this macro as well... I have a little voice emote letting people know I am pulling a mob to me when I'm in a group.|||thanks for answering the questions on the druid macros, xlorep!

kudos to you, and possibly a sticky?|||hehe, well... I just have a lot of fun figuring out little logic puzzles... these kinds of things are fun for me to screw around with. I have characters of every class, and have been formulating macros for all of them over time, the thing is, that as a character levels, that character can get new abilities, so my macros are potentially changing to handle the new abilities. Other things get worked on based on my experience while I am playing... what works, what doesn't work, etc.

Eventually, I'll probably do more. I'd put these in the wowui site, except that my macros are almost perpetually being "beta tested" by me.|||i been trying to make a macro for my warrior that will use revenge if available, then sheild slam, but just shield slam if revenge isnt available... Somone else told me this isnt possible but u seem to know alot about macro's so i will put the question to you aswell..

(background- i recently got my 4 in set t4 bonus and like the combination of the +10% dmge proc from using revenge, but often find myself forgetting to click revenge right before i shield slam or wasting the proc on a devestate)